SIC^2 : Logiciel de Simulation Intégrée des Canaux et de leur Contrôle

Exemple de routine de calcul CPID

David Dorchies — 2009-10-22T15:06:47Z

La méthode PID correspond à un PID classique, avec filtre éventuel sur le terme dérivé, antiwindup et bande morte. Il est programmé de la manière suivante :

SUBROUTINE CPID(Reg)
 USE SIRENE_parametres, ONLY : LONG
 USE TEMPS , ONLY : T
 USE D_REGULATION, ONLY : Regulateur_t
 
 IMPLICIT NONE
 
 TYPE(Regulateur_t), INTENT(INOUT) :: Reg
 
 REAL(KIND=LONG), POINTER :: KP,N,TI,TD,AWU,EOLD,SE,DE
 REAL(KIND=LONG) :: E,STI,A1,A2,U2
 
 LOGICAL SATURE !< Détection de l'anti wind-up
 INTEGER :: iU !< Compteur pour les commandes U
 
 ! Pointeurs pour faciliter la lecture du code
 KP=>Reg%tPara(1)
 TI=>Reg%tPara(2)
 TD=>Reg%tPara(3)
 N=>Reg%tPara(4)
 AWU=>Reg%tPara(5)
 EOLD=>Reg%tPara(6)
 SE=>Reg%tPara(7)
 DE=>Reg%tPara(8)
 
 ! Calcul pour cette methode
 ! Nouvel ecart (e = y* - y)
 E=Reg%tY(1)%YTVal-Reg%tY(1)%VarY%V
 ! On gère une bande morte (POM 21/07/04)
 IF(ABS(E).LT.Reg%tY(IY)%DYMax) THEN
 E=0.
 ENDIF
 
 ! Terme integral (approximation de Tustin)
 IF(TI.NE.0.) THEN
 STI=KP*Reg%tU(1)%VarU%DT/TI*(EOLD+E)/2
 ELSE
 STI=0.
 ENDIF
 ! On gère l'antiwindup en utilisant le code de blocage du filtre de la commande :
 !> 0 = Fonctionnement libre normal
 !> 1 = Caractéristique volontairement bloquée (Valeur calée par Umin>=Umax à la lecture du XML)
 !> 2 = Caractéristique bloquée par problème de régulation (Umin, Umax, surverse, hors-loi vanne mixte)
 !> 3 = FiltreU => Umin atteint
 !> 4 = FiltreU => Umax atteint
 !> 5 = FiltreU => DUmin atteint
 !> 6 = FiltreU => DUmav atteint
 SATURE=Reg%tU(1)%FiltreU%iFlagBloc>=3 .AND. Reg%tU(1)%FiltreU%iFlagBloc/=5
 IF(AWU == 0. .OR. .NOT.SATURE) THEN
 SE=SE+STI
 ENDIF
 
 ! Terme derive
 IF(TD.NE.0.) THEN
 IF(N.EQ.0.) THEN
 ! Terme derive sans filtre (backward difference)
 ! Avec une consigne y* constante
 DE=KP/Reg%tU(1)%VarU%DT*TD*(E-EOLD)
 ELSE
 ! Terme derive avec filtre (backward difference)
 ! Avec une consigne y* constante
 A1=1/(1+N*Reg%tU(1)%VarU%DT/TD)
 A2=KP*N*A1
 DE=A1*DE+A2*(E-EOLD)
 ENDIF
 ENDIF
 
 ! Calcul de la commande
 Reg%tU(1)%VarU%V=KP*E+SE+DE
 ! Ancien ecart
 EOLD=E
 ! Si plusieurs U (SIMO) on duplique la meme ouverture
 ! (interessant dans le cas de plusieurs vannes identiques en parallele, en mode V par exemple)
 DO iU=1, Reg%nbrU
 Reg%tU(iU)%VarU%V = Reg%tU(1)%VarU%V
 ENDDO
 
END SUBROUTINE CPID

Télécharger

Si vous voulez un PID différent vous pouvez toujours copier cette routine dans un module USER et la modifier comme bon vous semble (dans ce cas faire aussi cela pour la routine LPID -> LUSER pour la lecture des paramètres)

La méthode PID

David Dorchies — 2009-10-22T15:06:46Z

La méthode PID correspondant à un contrôleur PID classique est programmée selon la routine CPID présentée ci-dessous. Vous pouvez vous inspirer de cette routine pour écrire une routine de calcul CUSER si vous voulez tester une variante de PID.

Pour la méthode PID ce sont les coefficients K, Ti, Td, N et Antiwindup au format (4(F8.2,1X),F8.2)

* Paramètres spécifiques
 * K Ti Td N AntiWup
 PS= -0.23 1245.20 0.00 5.00 0.00

La routine de lecture LPID de ces paramètres est donné ci-dessous. Vous pouvez vous inspirer de cette routine pour écrire une routine de lecture LUSER pour un module de régulation USER (USER1 à USER9).

Le but de l'antiwindup est d'arrêter d'intégrer les écarts sur les variables contrôlées par rapport aux consignes, lorsque l'actionneur est en saturation. Cela sert à éviter d'avoir un terme intégral trop important à rattraper lorsque la saturation est terminée.

Exemple de routine de lecture LPID

David Dorchies — 2009-10-22T15:06:45Z

Routine de lecture des paramètres spécifiques du PID :

!===============================================================================
!> Lecture des parametres specifiques pour la methode PID
!===============================================================================
SUBROUTINE LPID(U,PARA)
 USE SIRENE_parametres, ONLY : LONG
 USE F1 , ONLY : IERROR,IWARN,CWARN
 
 IMPLICIT NONE
 
 CHARACTER, INTENT(IN) :: U*(*)
 REAL(KIND=LONG), DIMENSION(*), INTENT(OUT) :: PARA
 INTEGER :: I
 
!-----Debut de la routine
!-----Lecture des parametres specifiques pour cette methode
 
!-----Debut de la routine
 READ(U,'(4(F8.2,1X),F8.2)',ERR=10) (PARA(I),I=1,5)
 PARA(6)=0
 PARA(7)=0
 PARA(8)=0
 RETURN
 10 CONTINUE
 IERROR=2
 
END SUBROUTINE LPID

Télécharger